guix: Add e2e-tests.scm.

This should have been added in
5e6596ac7decbe88c03314e543efe1922edce13f, but was forgotten!

1 files changed, 78 insertions, 0 deletions

diff --git a/.guix/e2e-tests.scm b/.guix/e2e-tests.scm
new file mode 100644
index 0000000..58ba480
--- /dev/null
+++ b/.guix/e2e-tests.scm
@@ -0,0 +1,78 @@
+;;; ravanan --- High-reproducibility CWL runner powered by Guix
+;;; Copyright © 2025 Arun Isaac <arunisaac@systemreboot.net>
+;;;
+;;; This file is part of ravanan.
+;;;
+;;; ravanan is free software: you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation, either version 3 of the License, or
+;;; (at your option) any later version.
+;;;
+;;; ravanan is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+;;; General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with ravanan.  If not, see <https://www.gnu.org/licenses/>.
+
+(define-module (e2e-tests)
+  #:use-module ((cwl-conformance) #:select (cwltest-suite-gexp))
+  #:use-module ((gnu packages bioinformatics) #:select (ccwl))
+  #:use-module (guix gexp)
+  #:use-module (ice-9 match))
+
+(define (ccwl-compile source-file)
+  #~(begin
+      (use-modules (rnrs io ports)
+                   (srfi srfi-26)
+                   (ice-9 match)
+                   (ice-9 popen))
+
+      (define (call-with-input-pipe command proc)
+        (match command
+          ((prog args ...)
+           (let ((port #f))
+             (dynamic-wind
+               (lambda ()
+                 (set! port (apply open-pipe* OPEN_READ prog args)))
+               (cut proc port)
+               (lambda ()
+                 (unless (zero? (close-pipe port))
+                   (error "Command invocation failed" command))))))))
+
+      (call-with-output-file #$output
+        (cut display
+             (call-with-input-pipe '(#$(file-append ccwl "/bin/ccwl")
+                                     "compile"
+                                     #$source-file)
+               get-string-all)
+             <>))))
+
+(define e2e-tools-ccwl-sources
+  `(("hello-world.scm" . ,(local-file "../e2e-tests/tools/hello-world.scm"))))
+
+(define e2e-tools
+  (file-union "e2e-tools"
+              (map (match-lambda
+                     ((ccwl-source-filename . ccwl-source-file)
+                      (let ((cwl-filename (string-append (basename ccwl-source-filename ".scm")
+                                                         ".cwl")))
+                        (list cwl-filename
+                              (computed-file cwl-filename
+                                             (ccwl-compile ccwl-source-file))))))
+                   e2e-tools-ccwl-sources)))
+
+(define e2e-test-suite
+  (file-union "e2e-test-suite"
+              `(("tests.yaml" ,(local-file "../e2e-tests/tests.yaml"))
+                ("tools" ,e2e-tools)
+                ("jobs" ,(local-file "../e2e-tests/jobs"
+                                     #:recursive? #t)))))
+
+(define-public e2e-tests
+  (program-file "e2e-tests"
+                (cwltest-suite-gexp (file-append e2e-test-suite "/tests.yaml")
+                                    (local-file "../e2e-tests/manifest.scm"))))
+
+e2e-tests