;;; guix-forge --- Guix software forge meta-service
;;; Copyright © 2023, 2024 Arun Isaac <arunisaac@systemreboot.net>
;;; Copyright © 2024 jgart <jgart@dismail.de>
;;;
;;; This file is part of guix-forge.
;;;
;;; guix-forge is free software: you can redistribute it and/or modify
;;; it under the terms of the GNU General Public License as published
;;; by the Free Software Foundation, either version 3 of the License,
;;; or (at your option) any later version.
;;;
;;; guix-forge is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with guix-forge.  If not, see
;;; <https://www.gnu.org/licenses/>.

(define-module (forge klaus)
  #:use-module (forge environment)
  #:use-module ((forge git) #:select (git-without-safe-directory-check))
  #:use-module (forge gunicorn)
  #:use-module (forge socket)
  #:use-module ((gnu packages check) #:select (python-nose python-pytest))
  #:use-module ((gnu packages python-build)
                #:select (python-setuptools python-wheel))
  #:use-module ((gnu packages python-web)
                #:select (python-flask python-werkzeug))
  #:use-module ((gnu packages python-xyz)
                #:select (python-dulwich python-humanize python-pygments))
  #:use-module (gnu system file-systems)
  #:use-module (guix build-system pyproject)
  #:use-module (guix build-system python)
  #:use-module (guix download)
  #:use-module (guix gexp)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix packages)
  #:export (klaus-gunicorn-app))

(define-public python-httpauth
  (package
    (name "python-httpauth")
    (version "0.4.1")
    (source (origin
              (method url-fetch)
              (uri (pypi-uri "httpauth" version))
              (sha256
               (base32
                "1m6rwvivg61l3h34hf6p6gkqmr69sb1c4k5ha379nxq0p8bfgahb"))))
    (build-system pyproject-build-system)
    (native-inputs
     (list python-pytest
           python-setuptools
           python-wheel))
    (home-page "https://github.com/jonashaag/httpauth")
    (synopsis "WSGI HTTP Digest Authentication middleware")
    (description "@code{python-httpauth} is WSGI middleware that secures some/all
routes using HTTP Digest Authentication.")
    (license license:bsd-2)))

(define-public python-klaus
  (package
    (name "python-klaus")
    (version "3.0.1")
    (source (origin
              (method url-fetch)
              (uri (pypi-uri "klaus" version))
              (sha256
               (base32
                "1w6sl15llnkcg7kmnpn64awdiis061q2gijnhdx0ng7z4p1glapl"))))
    (build-system pyproject-build-system)
    (arguments
     (list #:tests? #f  ; tests fail
           #:phases
           #~(modify-phases %standard-phases
               (add-after 'unpack 'configure-git
                 (lambda* (#:key inputs #:allow-other-keys)
                   (for-each (lambda (file)
                               (substitute* file
                                 (("\"git\"")
                                  (string-append "\"" (search-input-file inputs "/bin/git") "\""))))
                             (list "klaus/ctagsutils.py"
                                   "klaus/repo.py"
                                   "klaus/utils.py"
                                   "tests/test_contrib.py"
                                   "tests/test_make_app.py")))))))
    (inputs
     ;; We use klaus to serve shared repositories. But, git's safe
     ;; directory check does not permit us to use shared
     ;; repositories. Disable it. The more long term solution is to rewrite
     ;; klaus to not use the git CLI at all. See
     ;; https://github.com/jonashaag/klaus/issues/322
     (list git-without-safe-directory-check))
    (native-inputs
     (list python-pytest
           python-setuptools
           python-wheel))
    (propagated-inputs
     (list python-dulwich python-flask python-httpauth
           python-humanize python-pygments python-werkzeug))
    (home-page "https://github.com/jonashaag/klaus")
    (synopsis "Simple git web viewer")
    (description "klaus is a simple, easy-to-set-up git web viewer. It features

@itemize
@item Super easy to set up -- no configuration required
@item Syntax highlighting
@item Markdown + RestructuredText rendering support
@item Pull + push support (Git Smart HTTP)
@item Code navigation using Exuberant ctags
@end itemize")
    (license license:isc)))

(define* (klaus-gunicorn-app repository-directory
                             #:key
                             (klaus python-klaus)
                             (sockets (list (forge-unix-socket
                                             (path "/var/run/gunicorn/klaus/socket"))))
                             site-name)
  "Return a @code{<gunicorn-app>} object to deploy klaus.

@var{repository-directory} is the path to the directory containing git
repositories to serve.

@var{klaus} is the klaus package to use.

@var{sockets} is a list of @code{<forge-ip-socket>} or
@code{<forge-unix-socket>} objects describing sockets to listen on.

@var{site-name} is the name of the klaus site to be displayed in the
banner."
  (gunicorn-app
   (name "klaus")
   (package klaus)
   (wsgi-app-module "klaus.contrib.wsgi_autoreload")
   (sockets sockets)
   (environment-variables (cons (environment-variable
                                 (name "KLAUS_REPOS_ROOT")
                                 (value repository-directory))
                                (if site-name
                                    (list (environment-variable
                                           (name "KLAUS_SITE_NAME")
                                           (value site-name)))
                                    (list))))
   (mappings (list (file-system-mapping
                    (source repository-directory)
                    (target source))))))