ccwl: Support nested arrays.

* ccwl/ccwl.scm (construct-type-syntax): Construct types recursively
to support nested arrays.
(key->output): Recursively convert stdout types to File types.
* ccwl/cwl.scm (type->cwl): New function.
(input->cwl-scm, output->cwl-scm): Use type->cwl.
* tests/ccwl.scm (make-array-type): New function.
(construct-type-syntax-wrapper): New syntax.
("construct-type-syntax on primitive types", "construct-type-syntax on
array types", "construct-type-syntax on nested array types"): New
tests.
* tests/cwl.scm, doc/array-types.scm, doc/nested-array-types.scm: New
files.
* doc/ccwl.skb (Cookbook)[Array types]: New section.

7 files changed, 94 insertions, 22 deletions

diff --git a/ccwl/ccwl.scm b/ccwl/ccwl.scm
index 66a8ab7..5ae0761 100644
--- a/ccwl/ccwl.scm
+++ b/ccwl/ccwl.scm
@@ -132,11 +132,9 @@ compared using @code{equal?}."
 
 (define (construct-type-syntax type-spec)
   "Return syntax to build a type from @var{type-spec}."
-  ;; TODO: Does CWL support arrays of arrays? If so, support such
-  ;; recursive type definitions.
   (syntax-case type-spec (array)
     ((array member-type)
-     #'(make-array-type 'member-type))
+     #`(make-array-type #,(construct-type-syntax #'member-type)))
     (primitive-type
      #''primitive-type)))
 
@@ -714,6 +712,14 @@ a <key> object, in STEPS, a list of <step> objects. If no such
 <output> object is found, return #f. Note that the returned syntax is
 only applicable to construct <output> objects for workflows, not in
 commands."
+  (define (stdout->file-type type)
+    "Recursively convert stdout types in @var{type} to File types."
+    (cond
+     ((array-type? type)
+      (make-array-type (stdout->file-type (array-type-member-type type))))
+     ((eq? type 'stdout) 'File)
+     (else type)))
+
   (and-let* ((step-with-output (find (lambda (step)
                                        (eq? (step-id step)
                                             (key-step key)))
@@ -734,17 +740,7 @@ commands."
                                  (cwl-key-address key))
               (key-name key))
              ;; Convert stdout type outputs to File type outputs.
-             (let ((type
-                    (cond
-                     ((eq? (output-type output-for-key)
-                           'stdout)
-                      'File)
-                     ((and (array-type? (output-type output-for-key))
-                           (eq? (array-type-member-type (output-type output-for-key))
-                                'stdout))
-                      (make-array-type 'File))
-                     (else
-                      (output-type output-for-key)))))
+             (let ((type (stdout->file-type (output-type output-for-key))))
                ;; If step scatters, convert to an array type.
                (if (null? (step-scattered-inputs step-with-output))
                    type
diff --git a/ccwl/cwl.scm b/ccwl/cwl.scm
index cdb4503..cdd65ca 100644
--- a/ccwl/cwl.scm
+++ b/ccwl/cwl.scm
@@ -97,15 +97,19 @@ association list."
                               (scatterMethod . ,(step-scatter-method step)))))))
                    (workflow-steps workflow)))))
 
+(define (type->cwl type)
+  "Render @var{type} into a CWL tree."
+  (if (array-type? type)
+      `((type . array)
+        (items . ,(type->cwl (array-type-member-type type))))
+      type))
+
 (define* (output->cwl-scm output #:key workflow?)
   "Render @var{output}, a @code{<output>} object, into a CWL tree. If
 @var{workflow?} is @code{#t}, this is a workflow output."
   `(,(output-id output)
     ,@(or (filter-alist
-           `(,@(if (array-type? (output-type output))
-                   `((type . ((type . array)
-                              (items . ,(array-type-member-type (output-type output))))))
-                   `((type . ,(output-type output))))
+           `((type . ,(type->cwl (output-type output)))
              ;; outputBinding is relevant only to commands, and
              ;; outputSource is relevant only to workflows.
              ,@(if workflow?
@@ -125,10 +129,7 @@ CWL YAML specification."
 (define (input->cwl-scm input)
   "Render @var{input}, a @code{<input>} object, into a CWL tree."
   `(,(input-id input)
-    ,@(if (array-type? (input-type input))
-          `((type . ((type . array)
-                     (items . ,(array-type-member-type (input-type input))))))
-          `((type . ,(input-type input))))
+    (type . ,(type->cwl (input-type input)))
     ,@(or (filter-alist
            `((label . ,(input-label input))
              (default . ,(and (not (unspecified-default? (input-default input)))
diff --git a/doc/array-types.scm b/doc/array-types.scm
new file mode 100644
index 0000000..1722d7c
--- /dev/null
+++ b/doc/array-types.scm
@@ -0,0 +1,2 @@
+(workflow ((foo #:type (array string)))
+  […])
diff --git a/doc/ccwl.skb b/doc/ccwl.skb
index 2e84d58..1ae35f2 100644
--- a/doc/ccwl.skb
+++ b/doc/ccwl.skb
@@ -332,6 +332,11 @@ to ,(emph "stage") the input file into the output directory. We may
 express this in ccwl using the ,(code "#:stage?") parameter to the
 inputs to be staged. Here is a rather concocted example.]
          (scheme-source "doc/staging-input-files.scm")))
+    (section :title [Array types]
+      (p [ccwl supports array types using the following syntax.]
+         (scheme-source "doc/array-types.scm"))
+      (p [Nested array types are also supported.]
+         (scheme-source "doc/nested-array-types.scm")))
     (section :title [Scatter/gather]
       (p [ccwl supports CWL's dotproduct scatter/gather feature using
 the following syntax. Here, the ,(code [other-messages]) input to the
diff --git a/doc/nested-array-types.scm b/doc/nested-array-types.scm
new file mode 100644
index 0000000..7968750
--- /dev/null
+++ b/doc/nested-array-types.scm
@@ -0,0 +1,2 @@
+(workflow ((foo #:type (array (array string))))
+  […])
diff --git a/tests/ccwl.scm b/tests/ccwl.scm
index 117f93f..6890017 100644
--- a/tests/ccwl.scm
+++ b/tests/ccwl.scm
@@ -27,6 +27,16 @@
 (define output
   (@@ (ccwl ccwl) output))
 
+(define make-array-type
+  (@@ (ccwl ccwl) make-array-type))
+
+(define-syntax construct-type-syntax-wrapper
+  (lambda (x)
+    (syntax-case x ()
+      ((_ type-spec)
+       ((@@ (ccwl ccwl) construct-type-syntax)
+        #'type-spec)))))
+
 (test-begin "ccwl")
 
 (test-assert "stdin input should not have inputBinding"
@@ -317,4 +327,16 @@
                       #:other '((secondaryFiles . ".fai"))))
            #f)))
 
+(test-eq "construct-type-syntax on primitive types"
+  'File
+  (construct-type-syntax-wrapper File))
+
+(test-eq "construct-type-syntax on array types"
+  (make-array-type 'File)
+  (construct-type-syntax-wrapper (array File)))
+
+(test-eq "construct-type-syntax on nested array types"
+  (make-array-type (make-array-type 'File))
+  (construct-type-syntax-wrapper (array (array File))))
+
 (test-end "ccwl")
diff --git a/tests/cwl.scm b/tests/cwl.scm
new file mode 100644
index 0000000..ba619ab
--- /dev/null
+++ b/tests/cwl.scm
@@ -0,0 +1,44 @@
+;;; ccwl --- Concise Common Workflow Language
+;;; Copyright © 2023 Arun Isaac <arunisaac@systemreboot.net>
+;;;
+;;; This file is part of ccwl.
+;;;
+;;; ccwl is free software: you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation, either version 3 of the License, or
+;;; (at your option) any later version.
+;;;
+;;; ccwl is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+;;; General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with ccwl.  If not, see <https://www.gnu.org/licenses/>.
+
+(use-modules (srfi srfi-64))
+
+(define type->cwl
+  (@@ (ccwl cwl) type->cwl))
+
+(define make-array-type
+  (@@ (ccwl ccwl) make-array-type))
+
+(test-begin "cwl")
+
+(test-equal "type->cwl on primitive types"
+  'File
+  (type->cwl 'File))
+
+(test-equal "type->cwl on array types"
+  '((type . array)
+    (items . File))
+  (type->cwl (make-array-type 'File)))
+
+(test-equal "type->cwl on nested array types"
+  '((type . array)
+    (items . ((type . array)
+              (items . File))))
+  (type->cwl (make-array-type (make-array-type 'File))))
+
+(test-end "cwl")