(define-module (tamil-computing-website)
  #:use-module ((gnu packages base) #:select (glibc make-glibc-utf8-locales))
  #:use-module ((gnu packages emacs) #:select (emacs-minimal))
  #:use-module (guix gexp)
  #:use-module (guix git-download)
  #:use-module (guix utils))

(define tamil-computing-website-source
  (local-file ".."
              "tamil-computing-website-checkout"
              #:recursive? #t
              #:select? (or (git-predicate (dirname (current-source-directory)))
                            (const #t))))

(define tamil-computing-website-gexp
  (with-imported-modules '((guix build utils))
    #~(begin
        (use-modules (guix build utils))

        ;; Set a Tamil locale to support Tamil filenames.
        (setenv "GUIX_LOCPATH" #$(file-append (make-glibc-utf8-locales
                                               glibc
                                               #:locales (list "ta_IN")
                                               #:name "glibc-tamil-locales")
                                              "/lib/locale"))
        (setlocale LC_ALL "ta_IN.utf8")
        (setenv "LC_ALL" "ta_IN.utf8")
        
        (copy-recursively #$tamil-computing-website-source
                          (getcwd))
        (setenv "HOME" "/tmp")
        (invoke #$(file-append emacs-minimal "/bin/emacs")
                "--script" "build.el")
        (copy-recursively "site" #$output))))

(define-public tamil-computing-website
  (computed-file "tamil-computing-website" tamil-computing-website-gexp))

tamil-computing-website