#!r6rs
;;; -*- mode: scheme -*-
;;; run64 --- SRFI-64 test runner
;;; Copyright © 2022 Arun Isaac <arunisaac@systemreboot.net>
;;;
;;; This file is part of run64.
;;;
;;; run64 is free software: you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation, either version 3 of the License, or
;;; (at your option) any later version.
;;;
;;; run64 is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with run64.  If not, see <https://www.gnu.org/licenses/>.

(import (rnrs programs)
        (srfi srfi-1)
        (srfi srfi-64))

(define (assq-ref alist key)
  (cdr (assq key alist)))

(define (color code str)
  (string-append (string #\esc)
                 "["
                 (number->string code)
                 "m"
                 str
                 (string #\esc)
                 "[0m"))

(define (bold str)
  (color 1 str))

(define (red str)
  (color 31 str))

(define (green str)
  (color 32 str))

(define (yellow str)
  (color 33 str))

(define (magenta str)
  (color 35 str))

(define (make-runner)
  (let ((runner (test-runner-null)))
    (test-runner-on-group-begin! runner
      (lambda (runner suite-name count)
        (display suite-name)
        (display " ")))
    (test-runner-on-group-end! runner
      (lambda _
        (newline)))
    (test-runner-on-test-end! runner
      (lambda (runner)
        (let ((name (test-runner-test-name runner))
              (result (string-upcase
                       (symbol->string (test-result-kind runner))))
              (result-alist (test-result-alist runner)))
          (display (case (test-result-kind runner)
                     ((pass) (green "."))
                     ((fail) (red "F"))
                     ((xfail xpass) (yellow "X"))
                     ((skip) (yellow "S"))))
          (when (eq? (test-result-kind runner)
                     'fail)
            ;; Prepend test failure details to aux value.
            (test-runner-aux-value! runner
                                    (cons (cons (cons 'test-name (test-runner-test-name runner))
                                                (test-result-alist runner))
                                          (test-runner-aux-value runner)))))))
    ;; Initialize aux value to the empty list.
    (test-runner-aux-value! runner '())
    runner))

(define (headline text color)
  "Display headline TEXT in COLOR. COLOR is a function that wraps a
given string in an ANSI escape code."
  (display (color (string-append "==== " text)))
  (newline))

(define (main args)
  (let ((runner (make-runner)))
    (headline "test session starts" bold)
    (test-with-runner runner
      (for-each load (cdr args)))
    (newline)
    (unless (zero? (test-runner-fail-count runner))
      (headline "FAILURES" red)
      (for-each (lambda (failure)
                  (let ((name (assq-ref failure 'test-name))
                        (file (assq-ref failure 'source-file))
                        (line (assq-ref failure 'source-line)))
                    (when file
                      (display file)
                      (display ":")
                      (when line
                        (display line)
                        (display ":"))
                      (display " "))
                    (display name)
                    (newline)))
                (test-runner-aux-value runner))
      (newline))
    (headline
     (string-join
      (filter-map (lambda (count text color)
                    (if (zero? count)
                        #f
                        (color (string-append (number->string count)
                                              " " text))))
                  (list (test-runner-pass-count runner)
                        (test-runner-fail-count runner)
                        (test-runner-xpass-count runner)
                        (test-runner-xfail-count runner)
                        (test-runner-skip-count runner))
                  (list "passed" "failed"
                        "unexpected passes"
                        "expected failures"
                        "skipped")
                  (list green red yellow yellow yellow))
      ", ")
     (cond
      ((not (zero? (test-runner-fail-count runner)))
       red)
      ((or (not (zero? (test-runner-xpass-count runner)))
           (not (zero? (test-runner-xfail-count runner))))
       yellow)
      (else green)))
    (exit (zero? (test-runner-fail-count runner)))))

(main (command-line))